Lovely shape !

Here's a way to make a sphere with your boxes:

#version 3.1;

#include "colors.inc"
#include "golds.inc"

#declare Cx = -pi;
#declare Step = pi/30;
#while(Cx < pi)
 #declare Cy = -pi;
 #while(Cy < pi)
   box {
     -<1, 1, 1>, <1, 1, 1>
     scale 0.04
     translate -y
     rotate <degrees(Cx), degrees(Cy), 0>
     texture { T_Gold_3C }
   }
   #declare Cy = Cy + Step;
 #end // while
 #declare Cx = Cx + Step;
#end // while

light_source { <-2, 1, -2> color White }

background { color Blue/2 }

camera {
  location -3*z
  look_at <0, 0, 0>
}


Tor Olav


Zebu wrote:
> 
> Content-Transfer-Encoding: 8Bit
> 
> Found an interesting shape while trying to make a sphere...
> 
> If there's a math guru out there who knows how to translate this code to
> 
> make a sphere, don't hesitate  :-)
> 
> #declare Cx=-pi;
> 
> #declare Step=pi/30;
> 
> #while(Cx<pi)
> 
>  #declare Cy=-pi;
> 
>  #while(Cy<pi)
> 
>   box {<-.04,-.04,-.04>,<.04,.04,.04>
> 
>    texture { T_Gold_3C }
> 
>   rotate <degrees(Cx),degrees(Cy),00>
> 
>   translate <sin(Cx),cos(Cx)*(abs(Step-Cy))/2,sin(Cy)> }
> 
>  #declare Cy=Cy+Step;
> 
>  #end
> 
> #declare Cx=Cx+Step;
> 
> #end

Post a reply to this message